 /*
 * Europe (D,E,F,GB,I,NL) DOS Working Demo Install
 * ARE-24 (TM) Version 1.0 for DOS
 * Advanced Rendering Extension (TM)
 *
 * Copyright (C) 1993 KETIV Technologies, Inc.
 * Copyright (C) 1993 RenderStar Technology BV
 *
 */

@DefineProject
	@Name       = "ARE-24 Working Demo"
	@Version    = "1.0"
	@InDiskBell = @True
	@SubDir     = ""
	@OutDrive   = C
	@Requires @HardDisk
@EndProject

@DefineVars
	@Integer @DiskUse      = 3145728        // 3MB benodigd voor ARE24
	@Drive   @AutoCadDrive = C              // variabelen voor AutoCAD
	@Dir     @AutoCadDir    = ""
	@Dir     @AutoCadDirDos = "\\ACAD"
	@Dir     @AutoCadDirWin = "\\ACADWIN"
	@QString @ACad         = "ACAD"
	@QString @MenuDir      = "\\MENU"
	@QString @SupportDir   = "\\SUPPORT"
	@QString @ACadApp      = "ACADAPP"
	@QString @AutoCad      = ""
	@QString @AutoCadDos   = "AutoCAD for DOS"
	@QString @AutoCadWin   = "AutoCAD for Windows"
	@QString @AutoCadExe   = "\\ACAD.EXE"
	@Qstring @AutoCadAds   = "\\ACAD.ADS"
	@QString @OldACadAds   = "\\OLD_ACAD.ADS"
	@QString @AutoCadPgp   = "\\ACAD.PGP"
	@QString @OldACadPgp   = "\\OLD_ACAD.PGP"
	@QString @AppName      = "ARE24"        // variabelen voor ARE-24
	@QString @International = "\\INTNL"
	@QString @Are24        = "\\ARE24"
	@QString @Are24Mnu     = "\\ARE24.MNU"
	@QString @Are24Mnl     = "\\ARE24.MNL"
	@QString @Are24Pgp     = "\\ARE24.PGP"
	@QString @Are24Str     = "\\ARE_PRG.STR"
	@QString @OldAre24Str  = "\\OLD_PRG.STR"
	@QString @TempAre24Str = "\\TEMPPRG.STR"
	@QString @SubdirDOS    = "\\ARE24"
	@QString @SubDirWin    = "\\ARE24WIN"
	@Integer @ModifyAds    = @False
	@Integer @ModifyPgp    = @False
	@Integer @ExistenceAds = @False
	@Integer @ExistencePgp = @False
	@Integer @AlreadyInstalledPgp = @False
	@Integer @YesAre24     = @False
	@Integer @NoFullAre24  = @False
	@Integer @Are24DOS     = @False
	@Integer @Are24Win     = @False
	@Integer @ACadEnglish = @False          // taalversie AutoCAD
	@Integer @ACadGerman  = @False
	@Integer @ACadFrench  = @False
	@Integer @ACadItalian = @False
	@Integer @ACadSpanish = @False
	@Integer @HelpDutch   = @False          // taalversie ARE24 Help file
	@Integer @HelpEnglish = @False
	@Integer @HelpGerman  = @False
	@Integer @HelpFrench  = @False
	@Integer @HelpItalian = @False
	@Integer @HelpSpanish = @False
	@QString @Help        = ""
@EndVars

@Display
	@Move(0,1)
	   This program will install:
	@MoveCStr(3,22,14+16,"@Name Version @Version")
	@MoveCStr(4,24,14+16,"Advanced Rendering Extension")
	@MoveCStr(5,24,14+16,"   for AutoCAD R12 for DOS  ")
	@Move(6,1)
	   on your computer system. Please refer to the README.DOC file 
	   for the differences between this demo version and the complete  
	   version of ARE-24. Part of the texture library is from the 
	   ImageCELs (R) Designer Package, Copyright (C) 1989-1993 by 
	   IMAGETECTS (TM). ImageCELs is a registered trademark of IMAGETECTS.
	@Move(12,1)
	   Each question has a default answer. If the default answer
	   is correct, press the ENTER key in response to the question.
	   Otherwise, type the answer and then press the ENTER key or
	   use the up/down cursor keys.
	@Move(16,1)
	@LocalWindow(16,1)
				       @Pause
@EndDisplay

@Are24Dos = @True
@SubDir = @SubDirDos
@AutoCad = @AutoCadDos
@AutoCadDir = @AutoCadDirDos


DOARE: // spring hiernaar als er te weinig schijfruimte is of de directory bestaat al
@GetOutDrive @OutDrive
	@Suppress A
	@Suppress B
	@Move(1,1)
	   On which drive do you want to install @Name?
	@Move(12,1)
	@LocalWindow(12,37)
	@FlushOptions( )
@EndOutDrive

@GetSubdir @SubDir
	@Move(1,1)
	   Now you need to specify the directory where @Name
	   will be installed.
	@Move(8,1)
	@LocalWindow(8,45)
	@Prompt = " Which directory ([Enter] = @SubDir) ? "
@EndSubdir

@If (@DirExists("@OutDrive:@SubDir"))
	@GetOption
	@Move(1,1)
	   The directory @OutDrive:@SubDir
	   already exists (maybe @Name is already installed).
	@Move(4,1)
	   Do you want to continue and possibly overwrite an
	   existing @Name?
	@Move(12,1)
	@LocalWindow(12,38)
	@FlushOptions( )
	@Option 200 = "Yes, continue and overwrite an existing @Name"
	@Option 201 = "No,  change drive/directory"
	@Option 202 = "Exit Installation"
	@EndOption
	@If (200 [= @Option ) @Goto DOACAD @EndIf
	@If (201 [= @Option ) @Goto DOARE @EndIf
@EndIf
@If (202 [= @Option ) @Abort @EndIf

@If ((@NetBIOS) && (@DriveRemote(@OutDrive))) // installatie op netwerkdrive
@If (@DiskFree(@OutDrive) < @DiskUse)
	@GetOption
	@Move(1,1)
	   The selected directory @OutDrive@!:@SubDir
	   has only @Eval(@DiskFree(@OutDrive)/(1024*1024)) megabytes free.
	   @Eval(@DiskUse/(1024*1024)) megabytes are required to install @Name.
	@Move(5,1)
	   Change to a different directory or contact your network
	   administrator.
	@Move(8,1)
	   Do you want to change to a different directory?
	@Move(14,1)
	@LocalWindow(14,37)
	@FlushOptions( )
	@Option 100 = "Yes, change directory"
	@Option 101 = "Exit Installation"
	@EndOption
	@If (100 [= @Option ) @Goto DOARE @EndIf
@EndIf // @If (@DiskFree(
@Else // niet dus
@If (@DiskFree(@OutDrive) < @DiskUse)
	@GetOption
	@Move(1,1)
	   The selected drive (@OutDrive@!:) has only @Eval(@DiskFree(@OutDrive)/(1024*1024)) megabytes free.
	   @Eval(@DiskUse/(1024*1024)) megabytes are required to install @Name.
	@Move(4,1)
	   Do you want to change to a different drive?
	@Move(10,1)
	@LocalWindow(10,37)
	@FlushOptions( )
	@Option 100 = "Yes, change drive"
	@Option 101 = "Exit Installation"
	@EndOption
	@If (100 [= @Option ) @Goto DOARE @EndIf
@EndIf
@EndIf
@If (101 [= @Option ) @Abort @EndIf

DOACAD: // spring hiernaar indien AutoCad pad niet goed is
@GetOutDrive @AutoCadDrive
	@Suppress A
	@Suppress B
	@Move(1,1)
	   On which drive is @AutoCad located? 
	@Move(12,1)
	@LocalWindow(12,37)
	@FlushOptions( )
@EndOutDrive

@GetSubDir @AutoCadDir
	@Move(1,1)
	   Now you need to specify the directory where your
	   @AutoCad program is located.
	@Move(8,1)
	@LocalWindow(8,45)
	@Prompt = " Which directory ([Enter] = @AutoCadDir) ? "
@EndSubDir

@If (@Exists("@AutoCadDrive:@AutoCadDir@AutoCadExe")==@False)
	@GetOption
	@Move(1,1)
	   The file @AutoCadDrive:@AutoCadDir@AutoCadExe
	   could not be found (maybe @AutoCad has not
	   been installed).
	@Move(5,1)
	   If you want to continue, be sure to read your @Name
	   Installation and Performance Guide for information on
	   loading and running @Name.
	@Move(9,1)
	   Do you want to continue?
	@Move(15,1)
	@LocalWindow(15,38)
	@FlushOptions( )
	@Option 300 = "Yes, continue installation"
	@Option 301 = "No,  change AutoCAD drive/directory"
	@Option 302 = "Exit Installation"
	@EndOption
	@If (301 [= @Option ) @Goto DOACAD @EndIf
@EndIf
@If (302 [= @Option ) @Abort @EndIf


@GetOption // mogen we .ADS en .PGP veranderen
	@Move(1,1)
	   The installation program can modify your
	   @AutoCad support files, depending on how you
	   want to load and use @Name.
	@Move(5,1)
	   Do you want @AutoCadDrive:@AutoCadDir@AutoCadAds
	   to be modified?
	   This will automatically load @Name when
	   @AutoCad is loaded.
	@Move(10,1)
	   Do you want @AutoCadDrive:@AutoCadDir@SupportDir@AutoCadPgp
	   to be modified?
	   This will load the @Name default command aliases.
	@Move(19,1)
	@LocalWindow(19,37)
	@FlushOptions( )
	@Option 402 = "Yes, modify both files"
	@Option 400 = "Yes, modify @ACad.ADS only"
	@Option 401 = "Yes, modify @ACad.PGP only"
	@Option 403 = "No,  just continue"
	@Option 404 = "Exit Installation"
@EndOption
@If (400 [= @Option ) @ModifyAds = @True                    @EndIf
@If (401 [= @Option )                    @ModifyPgp = @True @EndIf
@If (402 [= @Option ) @ModifyAds = @True @ModifyPgp = @True @EndIf
@If (404 [= @Option ) @Abort @EndIf


@If (@ModifyAds) // controleer of ACAD.ADS bestaat
	@ExistenceAds = @Search( "@AutoCadDrive:@AutoCadDir@AutoCadAds", "@ACADApp", 0 )
	@YesAre24     = @Search( "@AutoCadDrive:@AutoCadDir@AutoCadAds", "@AppName", 1 )
	@NoFullAre24  = @Search( "@AutoCadDrive:@AutoCadDir@AutoCadAds", "@OutDrive:@Subdir@Are24", 0 )
	@If (@ExistenceAds < 0) // ACAD.ADS bestaat niet
	@Display @Cls
	@Move(1,1)
	   Apparently, the file @AutoCadDrive:@AutoCadDir@AutoCadAds
	   does not exist.
	@Move(4,1)
	   A new @ACad@!.ADS file will be created with the contents:
	@Move(6,1)
			   @ACadApp
			   @OutDrive:@SubDir@Are24 
	@Move(16,1)
	@LocalWindow(16,1)
				       @Pause
	@EndDisplay
	@EndIf

	@If (@ExistenceAds == 0) // ACAD.ADS bestaat, geen ACADAPP
	@Display @Cls
	@Move(1,1)
	   The file @AutoCadDrive:@AutoCadDir@AutoCadAds
	   does not contain the line:
	@Move(4,1)
			   @ACadApp
	@Move(6,1)
	   The file will be modified to include this line.
	@Move(16,1)
	@LocalWindow(16,1)
				       @Pause
	@EndDisplay
	@EndIf

	@If (@YesAre24 == 0) // ACAD.ADS bestaat, geen ARE24
	@Display @Cls
	@Move(1,1)
	   The file @AutoCadDrive:@AutoCadDir@AutoCadAds
	   does not contain the line:
	@Move(4,1)
			   @OutDrive:@SubDir@Are24
	@Move(6,1)
	   The file will be modified to include this line.
	@Move(16,1)
	@LocalWindow(16,1)
				       @Pause
	@EndDisplay
	@EndIf

	@If ((@YesAre24 > 0) && (@NoFullAre24 == 0)) // ongeldig ARE24 pad
	@Display @Cls
	@Move(1,1)
	   The file @AutoCadDrive:@AutoCadDir@AutoCadAds
	   contains an invalid path to @Name.
	@Move(4,1)
	   Please delete this invalid line from the file after the
	   @Name installation has been completed.
	@Move(7,1)
	   The file will be modified to include the correct path:
	@Move(9,1)
			   @OutDrive:@SubDir@Are24
	@Move(16,1)
	@LocalWindow(16,1)
				       @Pause
	@EndDisplay
	@EndIf

@EndIf

@If (@ModifyPgp) // controleer of ACAD.PGP bestaat
	@ExistencePgp        = @Exists("@AutoCadDrive:@AutoCadDir@SupportDir@AutoCadPgp")
	@AlreadyInstalledPgp = @Search("@AutoCadDrive:@AutoCadDir@SupportDir@AutoCadPgp","; ARE-24 command aliases",0)
	@If (@ExistencePgp == @False) // ACAD.PGP bestaat niet
	@Display @Cls
	@Move(1,1)
	   Apparently, the file @AutoCadDrive:@AutoCadDir@SupportDir@AutoCadPgp
	   does not exist.
	@Move(4,1)
	   A new @ACad@!.PGP file will be created for the @Name default
	   command aliases.
	@Move(16,1)
	@LocalWindow(16,1)
				       @Pause
	@EndDisplay
	@EndIf
@EndIf

@GetOption // welke taalversie?
	@Move(1,1)
	   Please specify your @AutoCad language version.
	@Move(3,1)
	   If your @AutoCad language version is not listed
	   below, select the English version option.
	@Move(6,1)
	   Which language version of @AutoCad are you using?
	@Move(14,1)
	@LocalWindow(14,37)
	@FlushOptions( )
	@Option 501 = "English version"
	@Option 502 = "French  version"
	@Option 503 = "German  version"
	@Option 504 = "Italian version "
	@Option 505 = "Spanish version"
	@Option 500 = "Exit Installation"
@EndOption
@If (501 [= @Option ) @ACadEnglish = @True @EndIf
@If (502 [= @Option ) @ACadFrench  = @True @EndIf
@If (503 [= @Option ) @ACadGerman  = @True @EndIf
@If (504 [= @Option ) @ACadItalian = @True @EndIf
@If (505 [= @Option ) @ACadSpanish = @True @EndIf
@If (500 [= @Option ) @Abort @EndIf

@GetOption // welke helpfile?
	@Move(1,1)
	   Please specify the language for the @Name help file.
	@Move(3,1)
	   If the language you want is not listed below, select
	   the English help file.
	@Move(6,1)
	   Which language of the @Name help file do you want?
	@Move(15,1)
	@LocalWindow(15,37)
	@FlushOptions( )
	@Option 702 = "English language"
	@Option 703 = "French  language"
	@Option 704 = "German  language"
	@Option 705 = "Italian language"
	@Option 706 = "Spanish language"
	@Option 701 = "Dutch   language"
	@Option 700 = "Exit Installation"
@EndOption
@If (701 [= @Option) @HelpDutch   = @True @EndIf
@If (702 [= @Option) @HelpEnglish = @True @EndIf
@If (703 [= @Option) @HelpFrench  = @True @EndIf
@If (704 [= @Option) @HelpGerman  = @True @EndIf
@If (705 [= @Option) @HelpItalian = @True @EndIf
@If (706 [= @Option) @HelpSpanish = @True @EndIf
@If (700 [= @Option) @Abort @EndIf

/////////////////////////////////////////////////////////////////////

@DefineDisk
	@Label = "ARE-24 disk 1"
	@F README.DOC @O README.DOC
	@BeginLib PROGRAM.001
		@F CONVERT.EXP @S 157504 @O BIN\CONVERT.EXP
		@F RENDER.EXP @S 240748 @O BIN\RENDER.EXP
		@F TREE1-2A.DWG @S 3725 @O BLKS\TREE1-2A.DWG
		@F TREE2-2B.DWG @S 4032 @O BLKS\TREE2-2B.DWG
		@F _ARECAM.DWG @S 5057 @O BLKS\_ARECAM.DWG
		@F _ARELTL.DWG @S 5036 @O BLKS\_ARELTL.DWG
		@F _ARELTP.DWG @S 4864 @O BLKS\_ARELTP.DWG
		@F _ARELTS.DWG @S 5151 @O BLKS\_ARELTS.DWG
		@F AREABOUT.DCL @S 1250 @O DCLS\AREABOUT.DCL
		@F AREABOX.SLB @S 42821 @O DCLS\AREABOX.SLB
		@F AREALERT.DCL @S 1150 @O DCLS\AREALERT.DCL
		@F ARECAM.DCL @S 7103 @O DCLS\ARECAM.DCL
		@F AREIO.DCL @S 905 @O DCLS\AREIO.DCL
		@F ARELIGHT.DCL @S 17103 @O DCLS\ARELIGHT.DCL
		@F AREMAT.DCL @S 2302 @O DCLS\AREMAT.DCL
		@F AREMOVIE.DCL @S 686 @O DCLS\AREMOVIE.DCL
		@F ARESCENE.DCL @S 31157 @O DCLS\ARESCENE.DCL
		@F ARESHDW.DCL @S 893 @O DCLS\ARESHDW.DCL
		@F AREUTIL.DCL @S 357 @O DCLS\AREUTIL.DCL
		@F AREVAR.DCL @S 3351 @O DCLS\AREVAR.DCL
		@F AREPRF.DFL @S 589 @O DEFAULTS\AREPRF.DFL
		@F AREREZ.DFL @S 253 @O DEFAULTS\AREREZ.DFL
		@F BASEUNIT.DFL @S 56 @O DEFAULTS\BASEUNIT.DFL
		@F INTERNAT.LDB @S 19378 @O DEFAULTS\INTERNAT.LDB
		@F SCENE.DFL @S 1344 @O DEFAULTS\SCENE.DFL
		@F USA.LDB @S 14681 @O DEFAULTS\USA.LDB
		@F WORLD.LDB @S 33804 @O DEFAULTS\WORLD.LDB
		@F ARE_ADB.STR @S 27620 @O INTNL\ARE_ADB.STR
		@F ARE_EXT.STR @S 56956 @O INTNL\ARE_EXT.STR
		@F ARE_PRG.STR @S 2336 @O INTNL\ARE_PRG.STR
		@F ARE_SPY.STR @S 6596 @O INTNL\ARE_SPY.STR
		@F RSTAR.TXT @S 3072 @O INTNL\RSTAR.TXT
		@F BLOCK-3C.GIF @S 5686 @O MATERIAL\IMAGECEL\BLOCK-3C.GIF
		@F BLUGR-1B.GIF @S 1847 @O MATERIAL\IMAGECEL\BLUGR-1B.GIF
		@F CEMEN-2C.GIF @S 1910 @O MATERIAL\IMAGECEL\CEMEN-2C.GIF
		@F LAWNV-3D.GIF @S 3386 @O MATERIAL\IMAGECEL\LAWNV-3D.GIF
		@F LGSHR-1A.GIF @S 19474 @O MATERIAL\IMAGECEL\LGSHR-1A.GIF
		@F LGSHR-2B.GIF @S 12159 @O MATERIAL\IMAGECEL\LGSHR-2B.GIF
		@F PAVER-3E.GIF @S 7691 @O MATERIAL\IMAGECEL\PAVER-3E.GIF
		@F IMAGECEL.TXT @S 5692 @O MATERIAL\IMAGECEL\IMAGECEL.TXT
		@F TREE1-2A.GIF @S 8043 @O MATERIAL\IMAGECEL\TREE1-2A.GIF
		@F TREE2-2B.GIF @S 18686 @O MATERIAL\IMAGECEL\TREE2-2B.GIF
		@F WOOD1-2A.GIF @S 5293 @O MATERIAL\IMAGECEL\WOOD1-2A.GIF
		@F WOOD1-2E.GIF @S 1667 @O MATERIAL\IMAGECEL\WOOD1-2E.GIF
		@F WOOD1-3B.GIF @S 7927 @O MATERIAL\IMAGECEL\WOOD1-3B.GIF
		@F WOOD3-2C.GIF @S 15272 @O MATERIAL\IMAGECEL\WOOD3-2C.GIF
		@F ARE24.PAL @S 9247 @O MATERIAL\ARE24.PAL
		@F ARE24_IN.MAT @S 3260 @O MATERIAL\ARE24_IN.MAT
		@F BLACK.GIF @S 813 @O MATERIAL\BLACK.GIF
		@F CLOUDS.GIF @S 46466 @O MATERIAL\CLOUDS.GIF
		@F DECK1.GIF @S 9687 @O MATERIAL\DECK1.GIF
		@F FOREST1.GIF @S 71298 @O MATERIAL\FOREST1.GIF
		@F LOGO.GIF @S 4828 @O MATERIAL\LOGO.GIF
		@F REFLEC.GIF @S 29831 @O MATERIAL\REFLEC.GIF
		@F RENDER.RC1 @S 1562 @O MATERIAL\RENDER.RC1
		@F SHAKE.GIF @S 17040 @O MATERIAL\SHAKE.GIF
		@F WHITE.GIF @S 813 @O MATERIAL\WHITE.GIF
		@F ARE24.MNL @S 28 @O MENU\ARE24.MNL
		@F ARE24.MNU @S 95108 @O MENU\ARE24.MNU
		@F ARE24.PGP @S 525 @O MENU\ARE24.PGP
		@F HOUSE.DWG @S 870887 @O MODELS\HOUSE\HOUSE.DWG
		@F PORSCHE.DWG @S 343314 @O MODELS\PORSCHE\PORSCHE.DWG
		@F TUTOR3.DWG @S 143568 @O TUTOR\TUTOR3.DWG
		@F ARE24.EXP @S 315572 @O ARE24.EXP
		@F README.DOS @S 6976 @O README.DOS
	@EndLib
	@BeginLib HELPFILE.001
		@F ARE24.D  @S 64005 @O ARE24.HLP @Option 704
		@F ARE24.E  @S 56723 @O ARE24.HLP @Option 706
		@F ARE24.F  @S 62792 @O ARE24.HLP @Option 703
		@F ARE24.GB @S 53079 @O ARE24.HLP @Option 702
		@F ARE24.I  @S 48253 @O ARE24.HLP @Option 705
		@F ARE24.NL @S 51838 @O ARE24.HLP @Option 701
	@EndLib
@EndDisk

/////////////////////////////////////////////////////////////////////

@Finish
	@If (@DirExists("@AutoCadDrive:@AutoCadDir@SupportDir") == @False)
	@System("MKDIR @AutoCadDrive:@AutoCadDir")
	@System("MKDIR @AutoCadDrive:@AutoCadDir@SupportDir")
	@EndIf
	@Copy("@OutDrive:@SubDir@MenuDir@Are24Mnu","@AutoCadDrive:@AutoCadDir@SupportDir@Are24Mnu")
	@Copy("@OutDrive:@SubDir@MenuDir@Are24Mnl","@AutoCadDrive:@AutoCadDir@SupportDir@Are24Mnl")
	@If (@ACadEnglish==@False)
	@Copy("@OutDrive:@SubDir@International@Are24Str","@OutDrive:@SubDir@International@OldAre24Str")
	@Rename("@OutDrive:@SubDir@International@Are24Str","@SubDir@International@TempAre24Str")
	@EndIf
	@If (@ACadGerman)
	@Replace("@OutDrive:@SubDir@International@TempAre24Str","@OutDrive:@SubDir@International@Are24Str","BYBLOCK","VONBLOCK\n","BYLAYER","VONLAYER\n","CONTINUOUS","CONTINUOUS\n")
	@ElseIf (@ACadFrench)
	@Replace("@OutDrive:@SubDir@International@TempAre24Str","@OutDrive:@SubDir@International@Are24Str", "BYBLOCK","DUBLOC\n","BYLAYER","DUPLAN\n","CONTINUOUS","CONTINUOUS\n")
	@EndIf
	@If (@ACadItalian)
	@Replace("@OutDrive:@SubDir@International@TempAre24Str","@OutDrive:@SubDir@International@Are24Str", "BYBLOCK","DABLOCCO\n","BYLAYER","DALAYER\n","CONTINUOUS","CONTINUOUS\n")
	@ElseIf (@ACadSpanish)
	@Replace("@OutDrive:@SubDir@International@TempAre24Str","@OutDrive:@SubDir@International@Are24Str", "BYBLOCK","PORBLOQUE\n","BYLAYER","PORCAPA\n","CONTINUOUS","CONTINUOUS\n")
	@EndIf
	@If (@ACadEnglish==@False)
	@Delete("@OutDrive:@SubDir@International@TempAre24Str")
	@EndIf
	@If (@ModifyAds)
	@If (@ExistenceAds < 0) // geen ACAD.ADS
	@Write("@AutoCadDrive:@AutoCadDir@AutoCadAds","wt","@ACADApp\n")
	@Write("@AutoCadDrive:@AutoCadDir@AutoCadAds","at","@OutDrive:@SubDir@Are24\n")
	@EndIf // geen ACAD.ADS
	@If (@ExistenceAds == 0) // wel ACAD.ADS, geen ACADAPP
	@Copy("@AutoCadDrive:@AutoCadDir@AutoCadAds","@AutoCadDrive:@AutoCadDir@OldACadAds")
	@Write("@AutoCadDrive:@AutoCadDir@AutoCadAds","at","@ACADApp\n")
	@EndIf // wel ACAD.ADS
	@If ((@NoFullAre24 == 0) && (@YesAre24 >= 0)) // geen ARE24 pad
	@Write("@AutoCadDrive:@AutoCadDir@AutoCadAds","at","@OutDrive:@SubDir@Are24\n")
	@EndIf // geen ARE24 pad
	@Cls
	@If ((@YesAre24 > 0 ) && (@NoFullAre24 == 0)) // ongeldig ARE24 pad
	@If (@HelpDutch)
	@Move(7,1)
	   Het bestand @AutoCadDrive:@AutoCadDir@AutoCadAds bevat een 
	   onjuiste pad verwijzing naar de @Name. 
	   Verwijder deze onjuiste regel nadat @Name 
	   volledig geinstalleerd is.
	@Move(12,1)
	   Het bestand wordt veranderd met het juiste pad:
	@Move(14,1)
			   @OutDrive:@SubDir@Are24
	@Else
	@Move(7,1)
	   The file @AutoCadDrive:@AutoCadDir@AutoCadAds contains 
	   an invalid path to @Name. Please 
	   delete this invalid line from the file after the 
	   @Name installation has been completed.
	@Move(12,1)
	   The file will be modified to include the correct path:
	@Move(14,1)
			   @OutDrive:@SubDir@Are24
	@EndIf
	@Move(20,1)
	@LocalWindow(20,1)
	@Pause
	@EndIf // ongeldig ARE24 pad
	@EndIf // @If (@ModifyAds)
	@If (@ModifyPgp)
	@If (@ExistencePgp) // ACAD.PGP bestaat
	@Copy("@AutoCadDrive:@AutoCadDir@SupportDir@AutoCadPgp","@AutoCadDrive:@AutoCadDir@SupportDir@OldACadPgp")
	@If (@AlreadyInstalledPgp <= 0) // command aliases niet aanwezig
	@Append("@AutoCadDrive:@AutoCadDir@SupportDir@AutoCadPgp","@OutDrive:@SubDir@MenuDir@Are24Pgp")
	@EndIf // geen command aliases
	@Else // geen ACAD.PGP
	@Copy("@OutDrive:@SubDir@MenuDir@Are24Pgp","@AutoCadDrive:@AutoCadDir@SupportDir@AutoCadPgp")
	@EndIf // ACAD.PGP bestaat
	@EndIf // @If (@ModifyPgp)
	@Cls
	@If ((@ModifyAds == @False) && (@ModifyPgp))
	@If (@HelpDutch)
	@Move(7,1)
	   Het bestand @ACad@!.ADS is niet gewijzigd; dit betekent
	   dat de @Name niet automatisch wordt geladen
	   wanneer @AutoCad opgestart wordt.
	@Move(11,1)
	   Lees het bestand README.DOC voor meer informatie over 
	   het laden en gebruik van @Name.
	@Else
	@Move(7,1)
	   The installation program did not modify your @ACad@!.ADS 
	   file; therefore, @Name will not 
	   automatically be loaded when @AutoCad is loaded.
	@Move(11,1)
	   Please read the README.DOC file for more information 
	   on loading and using @Name.
	@EndIf
	@Move(20,1)
	@LocalWindow(20,1)
	@Pause
	@EndIf
	@Cls
	@If ((@ModifyPgp==@False) && (@ModifyAds))
	@If (@HelpDutch)
	@Move(7,1)
	   Het bestand @ACad@!.PGP is niet gewijzigd; dit betekent dat de 
	   @Name command aliases niet beschikbaar zijn.
	@Move(10,1)
	   Lees het bestand README.DOC voor meer informatie over 
	   het laden en gebruik van @Name.
	@Else
	@Move(7,1)
	   The installation program did not modify your @ACad@!.PGP 
	   file; therefore, the @Name default command 
	   aliases will not be loaded.
	@Move(11,1)
	   Please read the README.DOC file for more information 
	   on loading and using @Name.
	@EndIf
	@Move(20,1)
	@LocalWindow(20,1)
	@Pause
	@EndIf
	@Cls
	@If ((@ModifyPgp==@False) && (@ModifyAds==@False))
	@If (@HelpDutch)
	@Move(6,1)
	   De bestanden @ACad@!.ADS en @ACad@!.PGP zijn niet gewijzigd; dit 
	   betekent dat de @Name niet automatisch wordt 
	   geladen wanneer @AutoCad opgestart wordt, ook zijn 
	   de @Name command aliases niet beschikbaar.
	@Move(11,1)
	   Lees het bestand README.DOC voor meer informatie over 
	   het laden en gebruik van @Name.
	@Else
	@Move(6,1)
	   The installation program did not modify your @ACad@!.ADS 
	   and @ACad@!.PGP files; therefore, @Name will 
	   not automatically be loaded when @AutoCad is 
	   loaded and the @Name default command aliases 
	   will also not be loaded.
	@Move(12,1)
	   Please read the README.DOC file for more information 
	   on loading and using @Name.
	@EndIf
	@Move(20,1)
	@LocalWindow(20,1)
	@Pause
	@EndIf
	@Cls
	@If (@HelpDutch)
	@MoveCStr( 8,24,14,"@Name Version @Version")
	@MoveCStr( 9,24,14,"  Advanced Rendering Extension  ")
	@MoveCStr(10,24,14,"   voor @AutoCAD R12            ")
	@MoveCStr(12,24,14,"     is goed geinstalleerd.     ")
	@Move(14,1)
	  Het bestand README.DOC bevat de verschillen tussen deze demo
	  versie en de compleet uitgeruste versie van ARE-24.
	@Else
	@MoveCStr( 8,24,14,"@Name Version @Version")
	@MoveCStr( 9,24,14,"  Advanced Rendering Extension  ")
	@MoveCStr(10,24,14,"    for @AutoCAD R12            ")
	@MoveCStr(12,24,14," has been installed succesfully.")
	@Move(14,1)
	  Please read the README.DOC file about the differences between
	  this demoversion and the full-featured version of ARE-24.
	@EndIf
	@Move(20,1)
	@LocalWindow(20,1)
	@Pause

	@ChDrive @OutDrive
	@ChDir "@SubDir"

@EndFinish

/* end-of-file */

